checkers

1 files changed, 45 insertions, 0 deletions

diff --git a/config/.config/suckless.all/st/PKGBUILD b/config/.config/suckless.all/st/PKGBUILD
new file mode 100644
index 0000000..03d6f9f
--- /dev/null
+++ b/config/.config/suckless.all/st/PKGBUILD
@@ -0,0 +1,45 @@
+# Maintainer:
+
+pkgname=st-luke-git
+_pkgname=st
+pkgver=0.8.2.r1062.2087ab9
+pkgrel=1
+epoch=1
+pkgdesc="Luke's simple (suckless) terminal with vim-bindings, transparency, xresources, etc. "
+url='https://github.com/LukeSmithxyz/st'
+arch=('i686' 'x86_64')
+license=('MIT')
+options=('zipman')
+depends=('libxft')
+makedepends=('ncurses' 'libxext' 'git')
+optdepends=('dmenu: feed urls to dmenu')
+source=('git://github.com/LukeSmithxyz/st')
+sha1sums=('SKIP')
+
+provides=("${_pkgname}")
+conflicts=("${_pkgname}")
+
+pkgver() {
+	cd "${_pkgname}"
+	printf "%s.r%s.%s" "$(awk '/^VERSION =/ {print $3}' config.mk)" \
+		"$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+prepare() {
+	cd $srcdir/${_pkgname}
+	# skip terminfo which conflicts with ncurses
+	sed -i '/tic /d' Makefile
+}
+
+build() {
+	cd "${_pkgname}"
+	make X11INC=/usr/include/X11 X11LIB=/usr/lib/X11
+}
+
+package() {
+	cd "${_pkgname}"
+	make PREFIX=/usr DESTDIR="${pkgdir}" install
+	install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+	install -Dm644 README.md "${pkgdir}/usr/share/doc/${pkgname}/README.md"
+	install -Dm644 Xdefaults "${pkgdir}/usr/share/doc/${pkgname}/Xdefaults.example"
+}